Conjetura de Collatz

Ya se trató esta conjetura en este blog, pero desde el punto de vista de su experimentación en un Taller de Matemáticas

http://hojaynumeros.blogspot.com.es/2011/05/la-conjetura-de-collatz-en-un-taller-de.html

En esta ocasión se buscarán rutinas y funciones que nos ayuden a comprobar la conjetura para muchos números, así como encontrar sus cúspides y órbitas. Se ha escrito mucho sobre esta conjetura, por lo que aquí se desarrollará sólo ese aspecto.

Planteamiento

Para quienes no conozcan esta conjetura recordaremos su planteamiento:

Se toma un número entero positivo N cualquiera, por ejemplo el 13, y se le aplica la siguiente operación, a la que llamaremos función COLL(N):

• Si el número es par, se divide entre 2.
• Si el número es impar, se multiplica por 3 y se le suma 1.

En el caso del 13, como es impar, se le aplicará la segunda, y quedará COLL(13)=13*3+1=40.

La idea de la conjetura es que sigamos aplicando esta operación a todos los resultados que obtengamos, En nuestro caso sería COLL(40)=20 (por ser par), COLL(20)=10, COLL(10)=5, COLL(5)=3*5+1=16, COLL(16)=8, COLL(8)=4, COLL(4)=2, COLL(2)=1, y a partir del 1 se entra en el ciclo {4, 2, 1}

La conjetura afirma que este final en el 1 y el ciclo posterior ocurre para cualquier otro entero positivo. Sea cual sea el comienzo, se llegará al número 1. Todas las sucesiones construidas así terminarán en el ciclo 4, 2, 1.

Lo vemos con otro ejemplo:

COLL(6)=3, COLL(3)=10, COLL(10)=5, COLL(5)=16, COLL(16)=8, COLL(8)=4, COLL(4)=2, COLL(2)=1

Insistimos en que existen muchas publicaciones sobre esta conjetura y aquí sólo nos limitaremos a pequeñas comprobaciones. La más sencilla es mediante celdas en la hoja de cálculo.

Comprobación con celdas de hoja de cálculo

Escribimos el entero positivo inicial (lo podemos nombrar como semilla) en una celda, sea por ejemplo, la D4. En la celda inferior D5 escribimos SI(RESIDUO(D4;2)=0;D4/2;3*D4+1), que divide entre 2 el valor de la D4 si es par (porque entonces se verifica RESIDUO(D4;2)=0) y lo multiplica por 3 añadiendo 1 si es impar. En la imagen vemos el resultado para el número 132:

Al ser par el 132 se ha dividido entre 2. Ahora lo único que tenemos que hacer es rellenar esa fórmula hacia abajo y parar cuando aparezca un 1:

(Troceamos la imagen porque aparecen muchos números)

La conjetura ha sido comprobada hasta números muy grandes, por lo que puedes tener la seguridad de que llegarás siempre al valor 1. Al conjunto de números que se recorren hasta llegar a ese valor le podemos llamar órbita del número dado, que aquí son los 29 números que aparecen en la imagen. Al número mayor que hayamos alcanzado en la órbita le llamaremos cúspide. En este ejemplo la cúspide es el mismo 132.

De esta forma tan simple podemos comprobar la conjetura dentro del alcance de la herramienta que usamos. Si la órbita tiene una longitud grande este procedimiento puede alargarse. Por ello acudiremos ahora a la definición de funciones:

Funciones sobre la conjetura de Collatz

Ya hemos presentado COLL(N). Sería bueno introducir su versión en VBA para poder construir sobre ella otras funciones más complicadas. Su código es muy sencillo:

Public Function coll(n)
If n / 2 = n \ 2 Then coll = n / 2 Else coll = 3 * n + 1
End Function

No necesita grandes explicaciones. La condición n/2=n\2 equivale a indicar que n es par, ya que entonces el resultado de la división n/2 es idéntico al de la división entera n\2. El resto se entiende bien. Con esta función podemos reproducir las órbitas en columna de forma idéntica a como procedimos en el primer ejemplo.

En PARI el código es similar:

coll(n)=if(n/2==n\2,n/2,3*n+1)

En la imagen vemos el resultado de pedir coll(132)

Función orbicoll

A cualquier número entero le podemos asignar una cadena que contenga todos los números por los que “pasa” hasta llegar al 1, es decir, su órbita. En VBA podía ser esta:

Public Function orbicoll(n)
Dim b
Dim s$ ‘Cadena (string) para recoger los resultados
b = n: s$ = Str$(b) ‘La cadena comienza con el número inicial (semilla)
While b <> 1 ‘Se trabaja hasta llegar al 1
b = coll(b) ‘ En cada paso se aplica la función COLL
s$ = s$ + Str$(b) ‘Se incorpora el resultado al string
Wend
orbicoll = s$
End Function

En la imagen puedes comprobar la creación de la órbita del número 132:

Después puedes usar la prestación de convertir texto en columnas (antes debes copiar la órbita en otra celda mediante copiar valores) y crear un gráfico que abarque toda la órbita:

Puedes observar que arranca en 132 y termina en 1. Los tramos ascendentes representan números impares, y los descendentes a los pares.
Puedes seguir este proceso con cualquier otro número entero y seguir la evolución de su órbita.

En la imagen aparece la órbita del número 127, más compleja y con una cúspide cercana a 4500:

Función orbicoll en PARI

Es fácil la traducción de esta función a PARI:

coll(n)=if(n/2==n\2,n/2,3*n+1)
orbicoll(n)=my(b=n,s=Str(n));while(b<>1,b=coll(b);s=concat(concat(s," "),Str(b)));s

En la imagen se ha pedido la órbita de 127:

Estudia al código siguiente para la función lorbicoll, que devuelve el número de elementos de una órbita:

Public Function lorbicoll(n)
Dim a, b
a = 1: b = n
While b <> 1
b = coll(b)
a = a + 1
Wend
lorbicoll = a
End Function

Con ella podemos comprobar lo que ya sabemos, que 132 tiene una órbita de 29 elementos.

Con la versión PARI puedes abordar casos con números mayores:

coll(n)=if(n/2==n\2,n/2,3*n+1)
lorbicoll(n)=my(b=n,a=1);while(b<>1,b=coll(b);a+=1);a

Te proponemos comprobar que el número  871 es el que posee la órbita de más longitud entre los de tres cifras, y que contiene 179 elementos. De los de cuatro cifras el de órbita de más longitud es el número 6171, con 262 elementos.

Función cuspicoll

Del mismo modo que construimos la órbita de un número entero positivo, podemos encontrar su cúspide. El procedimiento será similar, pero, en lugar de añadir resultados a un string, tomaremos nota en cada paso del máximo valor que ha aparecido:

Public Function cuspicoll(n)
Dim a, b
a = n: b = n
While b <> 1
b = coll(b)
If b > a Then a = b
Wend
cuspicoll = a
End Function

La instrucción clave es If b > a Then a = b, que convierte a en el nuevo máximo si aparece un elemento b mayor que los precedentes.

Con las funciones definidas podemos construir un esquema en el que se analice el comportamiento de la conjetura de Collatz para una semilla dada:

Finales previsibles

Algunos tipos de números presentan una órbita bastante previsible. Por ejemplo:

Potencias de 2: a partir de ellos se entra en una ruta descendente y previsible que finaliza en el 1.

Números tipo (2^n-1)/3: Desembocan en una potencia de 2, por lo que también inician una ruta directa,  y esto ocurre una potencia sí y otra no, porque 2^n es del tipo 3k+1 o 3k+2 y al multiplicar por Si es 3k+1 es candidato a que (2^n-1)/3 sea entero, y si es del tipo 3k+2, la siguiente potencia será 6k+4, o sea del tipo 3k+1

Otros tienen recorrido corto, como el 6, el 10 o el 20.

Es normal que pensemos en que muchas órbitas pasarán por ellos, y existan pares de órbitas  que pasan ambas por el mismo punto de entrada, más o menos primario.

Podemos intentar ver si dos números presentan alguna coincidencia en sus órbitas, porque entonces compartirán final. No es difícil programar una función que nos devuelva un punto de coincidencia en las órbitas de dos números. En primer lugar necesitamos una función que nos indique si el número n pertenece a la órbita del número m. Puede ser esta:

Public Function enlacoll(m, n) As Boolean
Dim e As Boolean
Dim p
If m = n Then
e = True
Else
e = False
p = m  ‘p recorrerá la órbita de m
While Not e And p <> 1
p = coll(p)
If p = n Then e = True  ‘Si p es igual a n, sí pertenece
Wend
End If
enlacoll = e
End Function

Con esta función enlacoll(m,n) podemos saber si n pertenece a la órbita de m. Se puede organizar un esquema de cálculo:

En la imagen se ha verificado que 52 pertenece a la órbita de 57.

Coincidencia en las órbitas

Con la anterior función ya estamos preparados para encontrar la primera coincidencia entre dos órbitas. Si no existe una coincidencia anterior, se nos devolverá un cero. El código de la función es:

Public Function coincicoll(m, n)
Dim c, q
q = m
c = 0
While q > 1 And c = 0 ‘q recorre la órbita de m
If enlacoll(n, q) Then c = q ‘si q pertenece a la órbita de n, hay coincidencia
q = coll(q)
Wend
coincicoll = c
End Function

Con ella también podemos construir otro esquema de cálculo. En la imagen se comprueba que 125 y 126 comparten una subórbita de 95 elementos, que comienzan en 364.

Con estas ideas puedes construir otras muchas funciones, o emprender otras búsquedas. Sólo se ha pretendido en esta entrada dar ideas para comprobaciones y experimentaciones sobre la conjetura, ya de por sí bastante estudiada en otros aspectos.