Producto de cifras con incremento

El día 14 de mayo de 2020, @AnecdotesMaths publicó en Twitter la siguiente igualdad:

315 = (3+4)(1+4)(5+4)

En este blog estamos atentos a desarrollos a partir de cualquier curiosidad que encontremos, por lo que dedicaremos esta entrada a las igualdades del tipo

abc… = (a+k)(b+k)(c+k)…, donde a,b, c… son cifras de un número y k una constante entera.

El subrayado del primer miembro indica que son cifras del número y no producto.

Generalizamos a continuación la igualdad leída en Twitter.

El valor de k está acotado por el 10, ya que si aumentamos esta cantidad tendríamos:

(a+10)(b+10)(c+10)…>10*10*10*…> abc… ,

Sería imposible la igualdad pedida.

Para iniciar las búsquedas, necesitamos una función que nos devuelva las cifras de un número por separado. Puedes consultar los códigos para VBasic de Excel y Calc en la siguiente entrada de este blog

https://hojaynumeros.blogspot.com/2018/04/cancelaciones-anomalas-22.html

Allí se explican las funciones NUMCIFRAS (número de cifras), CIFRA, (una cifra sola) y TROZOCIFRA (devuelve varias cifras)

En PARI puedes usar:

cutdigit(a, p, q)=(a%10^q)\10^(p-1)

Es equivalente a TROZOCIFRAS, ya que devuelve las cifras entre los órdenes p y q, con lo que si son iguales equivalen a una sola cifra.

Para el total de cifras, PARI permite usar esta expresión:

#Vec(Str(N))

Equivale a “cardinal del vector formado por la expresión en texto de N”

Con estas funciones, no es difícil encontrar ejemplos como los deseados.

Versión para Excel y Calc

Hemos elegido la siguiente función para encontrar los números que poseen la propiedad deseada:

Function ciframasconst(n)

Dim i, j, k, p

k = 0  ‘Esta constante, si es mayor que 0, indicará éxito

For i = 0 To 9 ‘La variable i es la constante que se suma a las cifras

p = 1 ‘Inicio del producto de cifras

For j = 1 To numcifras(n)

p = p * (cifra(n, j) + i) ‘Se construye el producto de cifras aumentadas

Next j

If p = n Then k = i ‘Si el producto coincide con el número, tomamos nota de la constante sumada

Next i

ciframasconst = k ‘Si k>0, se da la propiedad

End Function

La función devuelve la constante que se suma a las cifras, de forma que si vale 0, es señal de que no se cumple la propiedad, y, en caso contrario, devuelve el valor de la constante que se suma. En la siguiente tabla figuran los primeros números que cumplen lo pedido y, junto a ellos, la constante que se suma:

12          2

18          1

24          2

35          2

50          5

56          2

90          6

120        4

210        5

315        4

450        5

780        5

840        6

1500      5

Vemos que, efectivamente, 315 cumple la igualdad para k=4, es decir, que 315=(3+4)(1+4)(5+4)

Otro ejemplo sería el 840, que la cumple para k=6:

840=(8+6)(4+6)(0+6)=14*10*6=840

Con esta función podemos extender la búsqueda hasta donde deseemos, recordando que solo ensayamos valores de k entre 0 y 10:

Los primeros números obtenidos son:

12, 18, 24, 35, 50, 56, 90, 120, 210, 315, 450, 780, 840, 1500, 3920, 4320, 4752, 7744, 16500,

24960,…

Están ya publicados en http://oeis.org/A055482

A055482                            There exists some k>0 such that n is the product of (k + digits of n).            

12, 18, 24, 35, 50, 56, 90, 120, 210, 315, 450, 780, 840, 1500, 3920, 4320, 4752, 7744, 16500, 24960, 57915, 59400, 60480, 91728, 269500, 493920, 917280, 1293600, 2419200, 3386880, 34992000, 266378112, 317447424, 1277337600, 3714984000, 14948388000, 48697248600, 460522782720, 896168448000

Versión en PARI

El algoritmo usado se traslada fácilmente al lenguaje PARI:

cutdigit(a, p, q)=(a%10^q)\10^(p-1)

prod_cifr_inc(n,k)=my(m=#Vec(Str(n)),p=1,i);for(i=1,m,p=p*(cutdigit(n,i,i)+k));p

for(i=1,10^6,for(k=1,9,if(i==prod_cifr_inc(i,k),print1(i,", "))))

Da los mismos resultados:

Primera variante

En lugar de producto de cifras incrementadas podemos usar la suma de sus cuadrados, es decir, que se cumpla la igualdad

 abc…=(a+k)^2+(b+k)^2+(c+k)^2

La acotación para k puede ser más amplia, por ejemplo, la raíz cuadrada del número N dividido entre el número de cifras. Así, 6754 podría alcanzar la cota 41 en la base de cada sumando:

6754>4*41^2=6724

El uso de valores de k de dos cifras complicaría una cuestión que solo es lúdica, por lo que seguiremos dándole valores entre 1 y 9. Dejamos abierta una ampliación de valores.

Un pequeño cambio en la función ciframascons nos devolvería los primeros números que cumplen esta condición:

20          2

40          2

106        3

114        4

118        2

121        5

146        3

158        2

171        4

230        7

274        5

325        7

413        9

469        6

481        8

Así, 325 coincide con la suma de los cuadrados de las cifras incrementadas estas en 7 unidades:

325=(3+7)^2+(2+7)^2+(5+7)^2=100+81+144

Con cubos

Si en lugar de cuadrados usamos cubos, obtenemos este otro listado:

141        1

251        1

440        2

532        2

560        1

1036      3

1307      3

1471      3

2240      6

2313      6

2609      3

2917      3

3016      6

3878      3

4799      3

Tomamos como ejemplo 3878, que con la constante igual a 3 cumple:

3878=(3+3)^3+(8+3)^3+(7+3)^3+(8+3)^3=216+1331+1000+1331

Dejamos como ampliación de quien nos lea la búsqueda de casos distintos. Por ejemplo, se podrían usar trozos de cifras en lugar de cifras aisladas.

Representación de Zeckendorf

Cada entero positivo puede expresarse de manera única como una suma de números distintos de Fibonacci no consecutivos. Este resultado se denomina teorema de Zeckendorf y la secuencia de números de Fibonacci que se suman se denomina representación de Zeckendorf. Se llaman así en honor al médico belga y matemático aficionado E. Zeckendorf.

Para descomponer un número en sumandos de la sucesión de Fibonacci, se ha demostrado que el mejor procedimiento es el de ir restando al número el término de Fibonacci mayor posible, hasta llegar a una diferencia que sea también de Fibonacci, con lo que se termina en un cero. El teorema correspondiente afirma que siempre se llegará a este término en las diferencias.

Puedes consultar el tema en

https://www.gaussianos.com/fibonacci-la-representacion-de-zeckendorf-y-la-conversion-entre-kilometros-y-millas/

Está desarrollado de forma amena y resulta interesante. Aquí nos limitaremos a la construcción del algoritmo, para lo que repasaremos algunas técnicas y propiedades relacionadas con la famosa sucesión.

Mayor término de Fibonacci menor que N

Hemos recordado que el procedimiento para la representación de Zeckendorf de un número N consiste en ir tomando el mayor término de Fibonacci posible entre los números menores o iguales que N. El problema ahora es cómo saber si un número pertenece a la sucesión de Fibonacci o no. Existe un criterio bastante simple, y es:

Un número N pertenece a la sucesión de Fibonacci si y sólo si 5N²+4 o 5N²-4 es un cuadrado perfecto.

(Ver http://gaussianos.com/algunas-curiosidades-sobre-los-numeros-de-fibonacci/)

Según eso, ésta puede ser la función que devuelva VERDADERO si un número es del tipo Fibonacci y FALSO en el caso opuesto:

Public Function esfibo(n) As Boolean 'devuelve verdadero si N es de Fibonacci

Dim f As Boolean

Dim a

f = False

a = 5 * n * n + 4

If escuad(a) Then f = True

a = 5 * n * n - 4

If escuad(a) Then f = True

esfibo = f

End Function

La función escuad ya está explicada muchas veces en este blog. Con el comando Buscar la puedes localizar. Dada esta función, para cualquier número N podemos definir esta otra función, antefibo, que devuelve el mayor número de Fibonacci que podemos restar de N. Su listado puede ser:

Function antefibo(n)

Dim i

i = n ‘Pudiera ser que N fuera de Fibonacci, y terminaría el proceso

While Not esfibo(i)

i = i – 1 ‘Vamos bajando números hasta encontrar el primer “Fibonacci”

Wend

antefibo = i

End Function

Con la ayuda de esta función ya es sencillo efectuar la descomposición de Zeckendorf. El listado siguiente recoge una función que devuelve todos los sumandos y su número de orden en la sucesión de Fibonacci:

Function zeckendorf$(n)

Dim p, q

Dim s$

s = "" ‘Contenedor para la solución

p = n

While p > 0

q = antefibo(p) ‘Primer sumando de Fibonacci

p = p - q

s = s + Str$(quefibo(q)) + "% " + Str$(q) + ", " ‘Se construye la solución

Wend

If s = "" Then s = "NO"

zeckendorf = s

End Function

Con esta función se puede construir un listado de representaciones de este tipo. Aquí puedes observar como ejemplo los números comprendidos entre 100 y 110.

En todos ellos, el primer sumando es 89, el número de Fibonacci número 11, y después 13, 8 o 21, hasta llegar a 1 o 2.

Hay que observar que los números de orden nunca son consecutivos. La razón estriba en que la suma de dos términos de Fibonacci consecutivos da lugar a otro mayor del mismo tipo, y ya habría sido elegido antes como sumando.

Para lo que sigue, puede ser útil incluir en el resultado el número de sumandos, para realizar clasificaciones. Por ejemplo, en el caso de 100 y 101 quedaría:

Nos informa, para futuras búsquedas, de que 100 presenta 3 sumandos, 89+8+3, y 101 presenta 4: 89+8+3+1.

En este procedimiento, el número 1, que puede definirse como F(2) o F(1), aparece siempre como F(2). Esto es importante en algunas propiedades de esta representación.

Si establecemos una búsqueda según el primer dígito, podremos clasificar los números según el número de sumandos. Vemos algunos ejemplos:

Un sumando

Si buscamos el valor de 1 como dígito inicial del resultado, obtendremos los mismos números de Fibonacci:

Para dos sumandos

Están publicados en http://oeis.org/A179242

Para tres:

Publicados en http://oeis.org/A179243

Así podríamos continuar, pero carece de interés.

Multiplicación de Fibonacci

La representación de Zeckendorf da lugar a un producto muy curioso, que consiste, dados dos números representados como suma de elementos de Fibonacci, formar la siguiente expresión:

Lo hemos escrito de forma abreviada, pero la idea es formar un sumatorio doble en el que cada sumando sea un número de Fibonacci cuyo índice sea la suma de los índices de cada uno de los factores.

Por ejemplo, si deseamos multiplicar 22 por 17, según las tablas de más arriba, 22 es una suma de números de Fibonacci de índices 8 y 2, mientras 17 se basa en 7, 4 y 2. Podemos formar una tabla de doble entrada, sumar índices y buscar el número de Fibonacci correspondiente:

Hemos ido sumando cada par de índices, como pueden ser 7 y 8. Su suma 15 la convertimos en F(15)=610, y así vamos procediendo con cada par. Al final, sumamos, y nos da como resultado 854.

Esta multiplicación es claramente conmutativa, pero Donald Knuth demostró que también es asociativa.

Es un reto comprobar esto con una función más automatizada que la propuesta en párrafos anteriores. Los resultados del tipo propuesto no son muy útiles para multiplicar 

Los sustituiremos por un formato más sencillo, en el que solo figurarán los índices. Omitimos el listado de la nueva función multizeck(n). Para quien tenga curiosidad, se adjunta en el Anexo.

Con esta función es fácil comprobar con Excel la propiedad asociativa. Lo vemos en el esquema construido al efecto:

Hemos tomado como ejemplo los números 23, 25 y 28. En primer lugar, por separado, hemos multiplicado 23 por 25 y 25 por 28, con resultados 1293 y 1573 respectivamente. Después se ha hallado el producto de ellos por el tercero, con el mismo resultado, 80557.

ANEXO

Función auxiliar

Function mzeck$(n)

Dim s$

Dim p, q, m

p = n

m = 0

s = ""

While p > 0

m = m + 1

q = antefibo(p)

s = s + Str$(quefibo(q)) + ","

p = p - q

Wend

mzeck = Str$(m) + "," + s

End Function

Función Producto

Function multizeck(a, b)

Dim u(20), v(20)

Dim s$

Dim m, p, q, i, j, z

s = mzeck(a)

m = InStr(1, s, ",")

p = Val(Left$(s, m - 1))

For i = 1 To p

s = Right(s, Len(s) - m)

m = InStr(1, s, ",")

If Len(s) > 0 Then u(i) = Val(Left$(s, m - 1))

Next i

s = mzeck(b)

m = InStr(1, s, ",")

q = Val(Left(s, m - 1))

For i = 1 To q

s = Right(s, Len(s) - m)

m = InStr(1, s, ",")

If Len(s) > 0 Then v(i) = Val(Left$(s, m - 1))

Next i

z = 0

For i = 1 To p

For j = 1 To q

z = z + fibo(u(i) + v(j))

Next j

Next i

multizeck = z

End Function