Regresos 12 - El problema del albañil

Este problema consiste en encontrar qué números N poseen un cuadrado N² que sea suma de cubos consecutivos. Se consideran cubos mayores que 1, pues todos los números triangulares poseen cuadrados que son suma de los primeros cubos, según la conocida fórmula 1³+2³+3³+4³+…n³=(n(n+1)/2)², y se desea eliminar un exceso de casos triviales.

Se exige también que el número de cubos sea al menos de tres. Según la página https://oeis.org/A238099, un ejemplo es el de

312^2 = 97344 = 14^3 + 15^3 + ... + 25^3.

El nombre y las condiciones del problema (por ejemplo, que se use el cuadrado del número) vienen de un ejercicio propuesto en un libro de Dudeney:

H. E. Dudeney, Amusements in Mathematics, Nelson, London, 1917, Problem 135.

Lo podemos consultar en https://archive.org/details/amusementsinmath00dude/page/24/mode/1up?view=theater

Su enunciado es un tanto artificioso, pero sirvió de base para estudiar con más profundidad las sumas de cubos consecutivos. El problema, como vemos, está resuelto, pero aquí estudiaremos los algoritmos que lo pueden resolver en una hoja de cálculo.

Hemos catalogado esta entrada como regreso, porque complementa otra nuestra de 2013, https://hojaynumeros.blogspot.com/2013/04/las-sumas-de-cubos-nos-llevan-los.html

En ella estudiábamos las sumas de cubos consecutivos, pero las derivábamos a otras cuestiones, como las ternas pitagóricas. Nos dedicaremos al problema del albañil, pero podremos referirnos a algún resultado contenido en esa entrada de hace años.

Desde hace un tiempo se prefieren en este blog las funciones que devuelven un texto. Son más explicativas y no dificultan búsquedas posteriores si se saben construir. En este caso del problema del albañil adaptaremos específicamente alguna otra función similar. La que presentamos da las soluciones de sumas de cuadrados sólo cuando se excluye el 1 y se exigen al menos tres sumandos. Su código para Excel y Libreoffice Calc es el siguiente:

Function albanil$(n)
Dim i, j, a, n1
Dim s$
Dim novale As Boolean

s = "" ‘Contenedor de la solución
n1 = n ^ 2 ‘Trabajamos con el cuadrado
i = Int(n1 ^ (1 / 3)) ’Máximo cubo contenido en n^2
novale = True ‘Suponemos que no hay solución
While i > 1 And novale ‘Desciende el mayor cubo hasta 2^3
a = i ^ 3 ‘Primera suma de cubos
j = i’Cubo inicial de la suma
While j > 1 And a <= n1 And novale
‘Se llega a la solución de tres cubos o más
If a = n1 And i - j > 2 Then s = s + "Desde" + Str$(j) + " hasta " + Str$(i): novale = False ‘novale ya no es cierto
j = j – 1’Desciende el primer cubo
a = a + j ^ 3’Se incrementa la suma
Wend
i = i – 1’Desciende el último cubo
Wend
If novale Then s = "NO"
albanil = s
End Function

Con esta función y un buscador podemos reproducir la lista publicada de soluciones:

Estos resultados coinciden con los publicados en https://oeis.org/A238099, luego nuestro primer objetivo está cumplido.

Usamos números triangulares

Recordamos la siguiente equivalencia:

Según ella, una suma de cubos que no comience con 1 será equivalente a una diferencia de los cuadrados de dos números triangulares.

Esto nos permite utilizar la diferencia entre los cuadrados de dos números triangulares para identificar las sumas de cubos. Así obtendríamos una variante alternativa a la vista en anteriores párrafos.

Para encontrar los dos números triangulares basta descomponer N en productos de suma por diferencia de dos números, ya que eso equivale a una diferencia de cuadrados. Una vez obtenidos se les exige que sean triangulares y que sus órdenes se diferencien en más de 3 unidades.

Descomponemos N en productos de la misma paridad, N=pq y después definimos a=(p+q)/2 y b=(p-q)/2, con lo que tendríamos los posibles triangulares. Es una técnica que hemos usado a menudo. Después analizamos si son triangulares con las funciones estriangular y ordentriang, muy usadas en este blog.

Function estriangular(n) As Boolean
Dim a
a = Int((Sqr(8 * n + 1) - 1) / 2)
If a * (a + 1) = 2 * n Then estriangular = True Else estriangular = False
End Function

Public Function ordentriang(n)
Dim k
If estriangular(n) Then k = Int((Sqr(8 * n + 1) - 1) / 2) Else k = 0
ordentriang = k
End Function

El código de esta función es:

Function albanil2$(n)
Dim i, j, p, q, a, b, n1
Dim s$
Dim novale As Boolean

s = "" ‘Contenedor de la solución
n1 = n ^ 2 ’Trabajamos con el cuadrado
i = 1 ‘Primer divisor
novale = True
While i <= n And novale
If n1 / i = n1 \ i Then ‘Es divisor
j = n1 / i ‘Divisor complementario
If (j - i) Mod 2 = 0 Then ‘Tienen la misma paridad los factores
p = (i + j) / 2: q = (j - i) / 2 ‘Vamos construyendo la diferencia de cuadrados
If estriangular(p) And estriangular(q) Then
a = ordentriang(p): b = ordentriang(q) ‘Son ambos triangulares
If a - b > 3 And b > 1 Then s = s + "Desde" + Str$(b + 1) + " hasta " + Str$(a): novale = False
End If
End If
End If
i = i + 1
Wend
If novale Then s = "NO"
albanil2 = s
End Function

En la entrada a la que regresamos hoy se termina considerando que los dos triangulares de la diferencia de cuadrados y el número N estudiado forman una terna pitagórica, pero este tema es preferible leerlo en la entrada original.

Con esto cumplimos nuestro objetivo, que era sólo algorítmico.

Derivada aritmética

Este original concepto fue presentado por el matemático español José Mingot Shelly en 1911 con el título "Una cuestión de la teoría de los números", trabajo presentado en el Tercer Congreso Nacional para el Progreso de las Ciencias, Granada. Es interesante su biografía, condicionada totalmente por la Guerra Civil española.

Como su nombre indica, esta derivada se basa en una operación similar a la de la derivada de un producto, y aplicada a números naturales. Podemos concretarla de esta forma:

D(0)=D(1)=0 (para completar la definición)
D(p)=1 si p es primo
D(ab)=aD(b)+bD(a) a>1, b>1 (Regla del producto)

Por ejemplo, D(10)=D(2*5)=2D(5)+5D(2)=2*1+5*1=7

Como la definición formal es similar a la de la derivada de una función, podemos extenderla a más factores, a potencias y a todos los números en general.

Así, en un número esfénico N=p*q*r, se tendrá D(N)=p*q+q*r+r*p.

Por ejemplo, D(30)=D(2*3*5)=2*3+3*5+5*2=31

Se generaliza fácilmente a las potencias de primos: D(p^k)=k*p^k-1

D(8)=D(2³)=3*2²=12
D(16)=D(2⁴)=4*2³=32

Veremos que nos conviene expresar la potencia de otra forma:

D(N)=D(p^k)=N*k/p

Caso general

Cualquier número se descompone en productos de potencias de primos. Con lo visto hasta ahora, se puede construir una forma de calcular la derivada aritmética en el caso general. Deberemos ir derivando cada potencia para multiplicarla por el resto de potencias de primos. Según el apartado anterior, cada potencia quedará multiplicada por su exponente y dividida entre su base. Extendemos a todas las potencias y queda:

Lo vemos mejor con un ejemplo:

D(360)=D(2³*3²*5)=360(3/2+2/3+1/5)=852

Estos resultados se pueden comprobar en https://oeis.org/A003415

Es fácil traducir todo esto a una función. En su primera parte es copia de nuestra rutina sacaprimos. Su salida es el conjunto de primos p() y el conjunto de exponentes ex(). A partir de ellos se construye la derivada.

Function derivada(n)
Dim f, a, e, nume, d, s
Dim p(20), ex(20)

‘Extrae primos y sus exponentes

a = n
f = 2
While f * f <= a
e = 0
While a / f = Int(a / f)
e = e + 1
a = a / f
Wend
If e > 0 Then
nume = nume + 1
p(nume) = f
ex(nume) = e
End If
If f = 2 Then f = 3 Else f = f + 2
Wend
If a > 1 Then
nume = nume + 1
p(nume) = a
ex(nume) = 1
End If

‘Fin de la extracción de primos

 s = 0 ‘Factor que multiplica a n
For f = 1 To nume
s = s + n*ex(f) / p(f) ‘Se suman los cocientes n*e/p
Next f
derivada = s
End Function

Hemos dimensionado los primos a 20 distintos, pues la gran mayoría de los números que tratamos tienen menos primos en su descomposición factorial. La misma idea usa la programación en PARI en la página enlazada. Aquí se puede comprobar la diferente potencia entre PARI y VBASIC:

(PARI) A003415(n) = {local(fac); if(n<1, 0, fac=factor(n); sum(i=1, matsize(fac)[1], n*fac[i, 2]/fac[i, 1]))} /* Michael B. Porter, Nov 25 2009 */

Dejamos su análisis como ejercicio lúdico.

Con cualquiera de estas dos herramientas podemos construir una tabla de derivadas aritméticas:

Observamos que todos los números primos tienen derivada 1 por definición, y las potencias de primos siguen la suya propia, como D(8)=D(2³)=3*2²=12

Naturaleza de la derivada aritmética

Siguiendo una costumbre en este blog, destacaremos algunas derivadas aritméticas según su tipo como números, primos, cuadrados, triangulares,…Publicamos a continuación una muestra:

Derivadas primas

Si añadimos a la búsqueda la condición de que la derivada sea prima, obtenemos este listado:

En la primera columna figuran los valores de N, y en la segunda las derivadas primas. Si siguiéramos buscando, observaríamos que muchos valores, como 191, se repiten bastante. Hemos añadido una columna más para comprobar que N es libre de cuadrados. En la página https://oeis.org/A157037 figuran los valores de N, y en ella se razona el porqué de que N no contenga divisores cuadrados.

Derivadas cuadradas

Deberemos en este caso excluir los casos en los que N es primo, pues nos llenarían las tablas con el valor cuadrado 1. Así que buscaremos derivadas cuadradas sólo para valores compuestos de N. El resultado es:

También están publicadas, en concreto en https://oeis.org/A256706

Por ejemplo, D(291)=D(3*97)=1*97+3*1=100=10²

Derivadas triangulares

Si exigimos que la derivada sea un número triangular, se encuentran muchos ejemplos. Estos son los primeros:

Esta sucesión parece estar inédita. El autor del blog no la va a publicar, y autoriza aquí su publicación por parte de otra persona.

Derivada que es potencia no trivial

Entre los valores de las derivadas aritméticas figuran, además de los cuadrados, otras potencias con exponentes mayores. Estos son los primeros valores:

Por ejemplo, D(108)=D(2²*3³)=108(2/2+3/3)=216=6³

También está inédita, aparentemente

Derivada de N igual a N

En la tabla anterior figura que la derivada de 27 es también 27. Buscaremos a continuación si existen más casos similares:

Basta observar la tabla para comprobar cuándo ocurre esto, y qué demostración sencilla es posible. Lo dejamos abierto a nuestros lectores.

Derivada múltiplo del número

Hemos observado derivadas que son iguales o el doble que el número dado. También existen casos en los que es un múltiplo mayor. Estos son los primeros casos:

Según lo explicado hasta ahora, esto ocurre cuando la suma de los cocientes entre los exponentes de los factores primos y ellos mismos es un número entero. Nos fijamos, por ejemplo en el número 6912=2⁸*3³, en el que esa suma es 8/2+3/3=5, y esa es la causa de que su derivada sea un múltiplo con cociente 5.

Esto traslada la cuestión a saber qué números cumplen la propiedad. Es fácil ver que no sólo la suma de esos cocientes ha de ser entera, sino que han de serlo cada uno por separado, pues al ser primos los denominadores no se podrán agrupar en sumas enteras esos cocientes si ellos no lo son.

Divisor propio mayor que la raíz cuadrada

 

Explorando por OEIS, encontré un tipo de números en https://oeis.org/A332269 y me ha apetecido desarrollar el tema mediante nuestras funciones en hoja de cálculo.

La idea es que en muchos números naturales N, un solo divisor propio de N es mayor que su raíz cuadrada, siendo todos los demás menores. Al ser propio, se descarta N, por lo que ese divisor ha de cumplir Sqr(N)<d<N, siendo Sqr la función raíz. Su valor máximo posible será N/2.

Por ejemplo, el número 27 posee como divisores propios 1, 3 y 9, siendo 9 el único divisor propio de 27 que es mayor que la raíz cuadrada de 27=5,19. Con este ejemplo ya tenemos un resultado, y es que los cubos de los números primos presentan esta propiedad.

Su búsqueda con Vbasic de Excel y Calc es bastante sencilla. Se puede desarrollar con esta función:

Function undivisor(n)
Dim k, m, d As Long
Dim r

r = Sqr(n) ’Cálculo de la raíz cuadrada
m = 0 ‘Contador de divisores
k = Int(n / 2) ‘Máximo divisor propio posible
While k > r ‘Contamos divisores mayores que la raíz
If n / k = n \ k Then d = k: m = m + 1
k = k - 1
Wend
‘Si el contador marca m=1 es de ese tipo
If m = 1 Then undivisor = d Else undivisor = 0
End Function

Devuelve un cero si no presenta la propiedad, y el mayor divisor si se cumple. Los primeros números con ella son:

6, 8, 10, 14, 15, 16, 21, 22, 26, 27, 33, 34, 35, 38, 39, 46, 51, 55, 57, 58, 62, 65, 69, 74, 77, 81, 82, 85, 86, 87, 91, 93, 94, 95, 106, 111, 115, 118, 119, 122, 123, 125, 129, 133, 134, 141, 142, 143, 145, 146, 155, 158, 159, 161, 166, 177, 178, 183, 185, 187, 194

Están publicados en https://oeis.org/A332269

En esta tabla observamos el cumplimiento de la condición:

 

En la página enlazada figuran algunos tipos de números con la propiedad pedida:

Semiprimos libres de cuadrados: Si N=pq, con p y q primos y p<q, es lógico que q sea el divisor único pedido. En el listado figuran muchos, como el 14=2*7, y 7 es mayor que la raíz cuadrada de 14.

Cubos y cuartas potencias de primos: En ambos casos se cumple, y el divisor es p² en el primer caso y p³ en el segundo. Así, en 16 el mayor divisor, 8, es el único mayor que la raíz cuadrada de 16, que es 4.

Simplificación

En la referida página de OEIS se incluye un comentario que nos permite simplificar la búsqueda, y es que si Sqr(N)<d<N, y d es único, también lo será N/d, que será divisor, pero que ahora se cumplirá N/d<Sqr(N), lo que nos permite buscar el divisor único entre 2 y Sqr(N).

El desarrollo de la función sería similar al presentado:

Function undivisor2(n)
Dim k, m, d As Long
Dim r

r = Sqr(n)
m = 0
k = 2 ‘Ahora se comienza en el 2, hasta la raíz cuadrada
While k < r ‘El resto se desarrolla igual
If n / k = n \ k Then d = k: m = m + 1
k = k + 1
Wend
If m = 1 Then undivisor2 = d Else undivisor2 = 0
End Function

Como era de esperar, resultan los mismos números:

Profundización

El número de divisores propios mayores que la raíz cuadrada coincide con el de los divisores menores, como vimos más arriba, ya que si D divide a N, también lo divide N/D. Esto nos permite cambiar la condición impuesta por la de que x*y=N tenga una sola solución si x es distinto de y y ambos mayores que la unidad. En ese caso, si x es menor que la raíz cuadrada de N, la otra variable y presentará un valor mayor que ella, con lo que se cumple la condición.

Si analizamos el valor de TAU(N) (número de divisores de N) observaremos que el número de pares x, y es igual a TAU(N)/2 si N es libre de cuadrados, y si (N,1) es un par, sólo deberá existir otro par (D,N/D), por lo que si TAU(N) vale cuatro, como ocurre en  los semiprimos libres de cuadrados p*q, con divisores (1, p, q, pq) y en los cubos de primos (1, p, p², p³), algo que ya se afirmó más arriba.

Si TAU(N) es mayor que 4, sólo se encuentran como ejemplos válidos las potencias cuartas de los números primos.

Ejemplos consecutivos

En la tabla figuran términos consecutivos. En la página de OEIS enlazada figuran varios tipos de números que forman pares de consecutivos. Es una curiosidad digna de leerse.

Primos brasileños

En esta entrada nos plantearemos qué números primos se pueden formar con la suma de las primeras potencias de un número, es decir, cuándo una suma del tipo 1+n+n²+n³+n⁴+n⁵+…será un número primo. No consideraremos el caso en el que un primo p sea igual a 1+n, ya que esto lo cumplen todos los primos.

Esta cuestión equivale a la búsqueda de números primos que sean “repitunos” en una base de numeración dada. Por ejemplo, 31(10=111(5, ya que las tres cifras 1 provienen de la igualdad 31=1+5+5².

Función caracterizadora

En nuestras últimas entradas estamos usando funciones para Excel y Calc que devuelven una cadena de texto con los resultados. Es un formato que nos da mucha información y que es susceptible de cambios sencillos para la búsqueda de otros objetivos.

En este caso usamos la siguiente función:

Function primo_sumpot$(n)
Dim p, k, m, q
Dim s$

If Not esprimo(n) Then primo_sumpot = "NO": Exit Function
k = 2 ‘Base de las potencias
p = 1’Suma de potencias
m = 0’ Exponente
s = ""’Contenedor del resultado
q = 0’ Contador de soluciones
While k < n
p = 1 + k: m = 1’Primera suma de potencias
While p <= n
m = m + 1’ Siguiente suma de potencias
p = p + k ^ m
If p >= n Then
If p = n Then q = q + 1: s = s + " # " + Str$(k) + ", " + Str$(m) ‘Solución
End If
Wend
k = k + 1: p = 1 + k: m = 1 ‘Siguiente base de potencias
Wend
If s = "" Then s = "NO" Else s = ajusta(q) + "## " + s
primo_sumpot = s
End Function

Si buscamos con ella los primeros primos que cumplen lo exigido, obtenemos:

Observamos que la mayoría de las soluciones son del tipo 1+k+k², como, por ejemplo, el 73, que equivale a 1+8+8².

El 31 presenta dos soluciones: 31=1+2+2²+2³+2⁴=1+5+5², lo que lo convierte en “repituno” en dos bases de numeración:

31(10 = 11111(2 = 111(5

Según una conocida fórmula, estos números también se caracterizan porque para un valor adecuado de m se cumple

En efecto, 31=(2⁵-1)/(2-1)=(32-1)/1=31

También 31=(5³-1)/(5-1)=124/4=31

Para que el resultado sea primo, m ha de ser primo, pues en caso contrario el cociente presentaría más de un factor. Es un razonamiento similar al usado en los primos de Mersenne.

Estos primos están publicados en https://oeis.org/A085104

Con el afán de nombrar ciertas clases de números, a estos se les conoce como “brasileños”, porque se dieron a conocer en una olimpiada matemática celebrada en Brasil (ver https://oeis.org/A125134/a125134.pdf)

Números brasileños

Si eliminamos la condición de que N sea primo, nos resultan los números brasileños. En nuestra función suprimimos la condición de que sea primo y los obtendremos:

Están publicados en https://oeis.org/A053696

No son objeto de estudio en esta entrada, pero es aconsejable la lectura de https://oeis.org/A125134/a125134.pdf

Valores de K

La siguiente lista contiene los primeros valores de K que pueden producir un primo con la expresión que estamos estudiando, con un exponente final fijado de antemano, mayor que 2 y con tope 100:

Observamos que hay bases primas entre estos primeros pasos:

Los primos resultantes, ordenados, están publicados en https://oeis.org/A023195

3, 7, 13, 31, 127, 307, 1093, 1723, 2801, 3541, 5113, 8011, 8191, 10303, 17293, 19531, 28057, 30103, 30941,…

 

Números Bogotá

Estos números fueron llamados así por Tomás Uribe y Juan Pablo Fernández, por su similitud con los números colombianos o autonúmeros. Es un homenaje a Bernardo Recamán, matemático colombiano

(Ver mi entrada https://hojaynumeros.blogspot.com/2015/03/autonumeros-1.html)

Su definición es simple: se trata de números N que equivalen a uno de sus divisores multiplicado por el producto de sus cifras (su raíz digital). Un ejemplo es el número 520, que se puede expresar como 52*5*2, o bien 8991 = 333*(3*3*3).

Para encontrarlos podemos recorrer todos los divisores del número y verificar que el cociente entre ambos coincide con el producto de cifras de ese divisor.

Ya hemos usado la función PRODUCIFRAS, pero reproducimos aquí su versión en VBASIC:

Public Function producifras(n)

Dim h, i, s, m

if n<10 then producifras=n:exit function

h = n  ‘la variable h recoge el valor de n

s = 1 ,‘El producto comienza con un 1 en la variable s

While h > 0  ‘Mientras queden cifras…

i = Int(h / 10) ‘Se queda con todas las cifras menos la última

m = h - i * 10 ‘La variable m recoge la última cifra

h = i ‘La variable h tiene una cifra menos

s = s * m ‘La última cifra se incorpora al producto

Wend

producifras = s

End Function

(ver https://hojaynumeros.blogspot.com/2018/09/permutacion-de-cifras-al-sumar-su.html)

Si contamos con esta función u otra similar, es fácil construir un criterio para saber si un número es Bogotá o no. Últimamente hemos optado por funciones en modo texto, porque en sus valores podemos incluir el número de soluciones y la expresión de cada una mediante el producto pedido (en este caso). En su listado se usan funciones que han aparecido en algún momento en mis publicaciones:

Function esbogota$(n)
Dim k, m, j, c
Dim noes As Boolean
Dim s$, t$

If n = 1 Then esbogota = "1*1": Exit Function’ Caso especial
k = 2 ‘Primer divisor
noes = True ‘Suponemos que no existe solución
s = "" ‘Contenedor de la solución
c = 0 ‘Contador de soluciones
While k <= n  And noes ‘Recorremos divisores incluido n
If n / k = n \ k Then ‘Es divisor
If n = k * producifras(k) Then ‘Es número Bogotá
t = ""
c = c + 1 ’Una solución más, y se construye a continuación
For j = numcifras(k) To 1 Step -1: t = t + "*" + ajusta(cifra(k, j)): Next j
s = s + " # " + Str$(k) + t
End If
End If
K=k+1 ‘Siguiente divisor
Wend
If s = "" Then s = "NO" Else s = ajusta(c) + " : " + s
esbogota = s
End Function

Para estar escrita en VBasic, no es lenta. Esta tabla es un ejemplo de su utilidad:

Aquí todos presentan una sola solución, pero entre las soluciones menores ya aparecen con dos o tres soluciones:

Estos son los primeros ejemplos con dos soluciones:

Están publicados en https://oeis.org/A336944

El listado de los primeros números de Bogotá de cualquier número de soluciones es:

1, 4, 9, 11, 16, 24, 25, 36, 39, 42, 49, 56, 64, 75, 81, 88, 93, 96, 111, 119, 138, 144, 164, 171, 192, 224, 242, 250, 255, 297, 312, 336, 339, 366,…

Están publicados en https://oeis.org/A336826

En esta página se proponen algunas cuestiones, y aquí plantearemos alguna otra.

Se advierte que los números “repidígitos” son todos de Bogotá, como es fácil razonar: 1111=1111*1*1*1*1. Entre ellos figuran algunos primos, que son los únicos posibles (ver https://oeis.org/A004022).

Ningún número múltiplo de 10 será de este tipo, porque la cifra 0 final anulará el producto de las cifras.

Se puede usar el hecho de que el producto de las cifras ha de ser 7-liso, ya que los números del 2 al 9 sólo poseen como factores primos 2, 3, 5 y 7. No hemos encontrado ventajas en usar este hecho

 (ver https://es.wikipedia.org/wiki/N%C3%BAmero_liso)

 
Números de Bogotá consecutivos

Al usar cifras, la existencia de estos pares será algo casual. Como poseemos la función esbogota(), bastará exigir que tanto N como N+1 sean de este tipo. Con un buscador apropiado se pueden encontrar:

Puedes consultar https://oeis.org/A336864

También podemos buscar el par (N, N+2):

Estos números no están publicados en OEIS.

Ya puestos, podemos buscar pares (N,2N):

Invitamos a los lectores a buscar más casos, que estarán inéditos muchos de ellos.

Números de Bogotá especiales

En los primeros números de este tipo figuran cuadrados, como 36 o 49. ¿Cuáles serán los siguientes? Para encontrarlos usaremos nuestra función ESCUAD junto a ESBOGOTA:

Esta sucesión también está inédita.

De igual forma se pueden buscar:

Triangulares

Oblongos N(N+1)

Potencias de exponente mayor que 2

Otras variantes

Con lo explicado, es fácil encontrar variantes de estos ejemplos. Si se busca en OEIS “Bogotá numbers”, se encuentran definiciones parecidas y algunas relaciones con los números de Recamán.